2015-08-05

Windows 10 のアップグレード USB メディアを Home と Pro で切り替えられるようにしてみた。

Windows 10 のアップグレード USB メディアを Home / Pro で作り変えるのが面倒になったので、無理矢理統合してみた。やっつけ仕事感満載です(笑)

一応、テスト済みですが、試験的な試みのため、実行は自己責任でお願いします。



前提として、
  • Windows 10 Home (32ビットおよび64ビット対応) の ISO イメージを持っている
  • Windows 10 Pro (32ビットおよび64ビット対応) の ISO イメージを持っている
  • Windows 10 アップグレード USB メディアを既に作ってある (なければ作って)
  • ある程度の Windows スキルを持ち合わせている
  • 私の適当な説明を噛み砕き、実行することができる
  • 失敗しても泣かない精神を持ち合わせている (そんなに大きな失敗はできないと思うけど)
ことを前提としています。
上から3つは、Windows 10 のメディアクリエーションツールがあればできます。4、5、6つ目は、やる気的なもの。

Windows 10 Home + Pro (32 + 64ビット) の全部入りを作るには、16 GB 以上の USB メモリが必要になります。



ISO ファイルの差分を確認


DAEMON Tools Lite を始めとするディスクイメージマウントソフトで、Windows 10 Home/Pro の両方のイメージをマウントし、「フォルダ内のファイル比較ツール」を使って差分を確認。

32ビット・64ビット両対応の ISO イメージ同士を比較するとおそらくこんな感じになると思う。


差分ファイルのリネーム


次に、作成済みであろうインストール USB メディアの改造に進む。 (作成していなければ、作成して欲しい。Home でも Pro でも構わない。)
前段階で、違いとして判明したファイルを全てリネームする。(状態が「変更」のものだけで、それ以外は無視していい。)
より具体的には、Windows 10 Home のインストールメディアであれば、拡張子「.home」を、Windows 10 Pro のインストールメディアであれば、拡張子「.pro」を追加する。決して、既についている拡張子を消してはいけない。

# 本当は、バッチファイルを書けばもっと簡単に済むんだけど、面倒いので……(笑)


差分ファイルの追加


リネーム処理が済んだら、ファイルを追加する。
具体的には、作成したインストール USB メディアとは違う方 (Home なら Pro。Pro なら Home) のインストール ISO イメージから、差分を確認した際に異なっていたファイルをすべてコピーする。
普通に考えたらわかるとは思うが、適当な場所にコピーすればいいと言うわけではなく、元あった位置関係 (ルートからのパス) を考慮して、配置すること。

また、隠しファイルは全て、非隠しファイルにしておくこと。 (ファイルを右クリック→「プロパティ」から変更してください。)

# こっちも、バッチファイルを書けばすごく簡単に済むんだけど、やっぱり面倒いので……(笑)


Home/Pro 切り替え用バッチファイルの作成


作成したインストール USB メディアのルートに、下の内容のバッチファイルを適当な名前 + 拡張子 .cmd or .bat で保存。もしかしたら、差分のファイルに違いがあるかもしれないので、そこら辺は上手く変えて下さい。

@echo off

:: ======================================================= ::
:: Windows 10 Home/Pro Switcher
:: Copyright (C) 2015 tag. All rights reserved.
:: http://karat5i.blogspot.jp/
:: ======================================================= ::

cd %~dp0

:: Home と Pro の差分ファイル (もしかしたら変更が必要かもしれない)
set FILES=boot\bcd boot\bcd.LOG1 efi\microsoft\boot\bcd efi\microsoft\boot\bcd.LOG1 efi\microsoft\boot\bcd{96ad2018-3f71-11e4-8950-00155dedb01b}.TM.blf efi\microsoft\boot\bcd{96ad2018-3f71-11e4-8950-00155dedb01b}.TMContainer00000000000000000001.regtrans-ms x64\sources\boot.wim x64\sources\install.esd x86\sources\boot.wim x86\sources\install.esd

:: メニュー
echo select a command
echo [0] Home
echo [1] Pro
echo:
set CMD=
set /p CMD=">"
if "%CMD%" equ "0" (
  goto Home
) else if "%CMD%" equ "1" (
  goto Pro
) else (
  goto End
)

:: Home 化の処理
:Home
for %%I in (%FILES%) do (
  echo %%I
  call :RenameForHome %%I
)
goto End

:: Pro 化の処理
:Pro
for %%I in (%FILES%) do (
  echo %%I
  call :RenameForPro %%I
)
goto End

:End
echo:
echo 作業が完了しました。
pause > nul
exit


::----- 以降、サブルーチン -----::

:: リネーム処理 (Home 化)
:RenameForHome
if exist ".\%~1.home" (
  ren "%~1" "%~nx1.pro"
  ren "%~1.home" "%~nx1"
)
exit /B %ERRORLEVEL%

:: リネーム処理 (Pro 化)
:RenameForPro
if exist "%~1.pro" (
  ren "%~1" "%~nx1.home"
  ren "%~1.pro" "%~nx1"
)
exit /B %ERRORLEVEL%
# windows-10-home-pro-switcher.cmd


切り替え


使い方はいたって簡単で、このバッチファイルをダブルクリックし、希望のエディションに対応した数字 (Home→0、Pro→1) を入力するだけ。
勝手に、対応した方のファイルに切り替わるはずです。 (エラーが発生した場合、これまでの準備にミスがあります。)


後は、適当に Windows 10 をインストールしてください。






# Amazon で販売中の Windows 10 のエディション名が "Home Premium" と "Professional" ってなってて気持ち悪いことこの上ない (Home と Pro が正しい) ので、さっさと直してくれないかな。

0 件のコメント :

コメントを投稿